Pass
{
    Name "Forward"
    Tags { "LightMode"="UniversalForward" }

    HLSLPROGRAM
    #pragma vertex VertDefault
    #pragma fragment Frag
    half4 Frag(Varyings input) : SV_Target
    {
        float3 n = normalize(input.normalWS);
        Light light = GetMainLight();
        half3 diffuse = light.color * saturate(dot(n, light.direction));
        half3 ambient = SampleSH(n);
        return half4(_BaseColor.rgb * (diffuse + ambient), 1);
    }
    ENDHLSL
}

Pass
{
    Name "Outline"
    // 没有 LightMode 标签 → URP 视为 "SRPDefaultUnlit"
    Cull Front

    HLSLPROGRAM
    #pragma vertex Vert
    #pragma fragment Frag
    Varyings Vert(Attributes input)
    {
        Varyings output;
        // 沿法线把顶点往外推，只画背面，就得到一圈“外壳”描边（第 14 章细讲）
        float3 positionWS = TransformObjectToWorld(input.positionOS.xyz);
        float3 normalWS = TransformObjectToWorldNormal(input.normalOS);
        output.positionCS = TransformWorldToHClip(positionWS + normalWS * _OutlineWidth);
        output.normalWS = normalWS;
        return output;
    }
    half4 Frag(Varyings input) : SV_Target { return _OutlineColor; }
    ENDHLSL
}

Pass
{
    Name "XRay"
    Tags { "LightMode"="CookbookXRay" }
    // 只在“被挡住”的地方画：深度比已有深度更远才通过
    ZTest Greater
    ZWrite Off
    Blend SrcAlpha OneMinusSrcAlpha

    HLSLPROGRAM
    #pragma vertex VertDefault
    #pragma fragment Frag
    half4 Frag(Varyings input) : SV_Target { return _XRayColor; }
    ENDHLSL
}