逐行读懂 URP Lit（第 10 章）- Unity URP Shader 教程

CHAPTER 10第 10 章

逐行读懂 URP Lit

打开 URP 14.0.12 的源码，沿着一个像素的计算路径，从 Lit.shader 一路读到 BRDF.hlsl：每一步输入什么、输出什么、和第 9 章的哪条公式对应、在哪里做了近似、近似了多少。

本章你会学到

Lit.shader 的属性、Pass、关键字各自的用途

SurfaceData、InputData、BRDFData 三个结构体如何串起整条流程

UniversalFragmentPBR 逐行做了什么，Forward+ 下有什么不同

DirectBRDFSpecular 与标准 D·V·F 的关系，以及它偏差多大

环境光的三件事：球谐、反射探针的 mip 选择与环境 BRDF 近似

自己调用 UniversalFragmentPBR 写“最小 Lit”，并把光照拆成四项调试

阅读说明本章所有源码都摘自 Unity 2022.3.62f3 工程中 Library/PackageCache/com.unity.render-pipelines.universal@14.0.12/（下文简称 URP）和 com.unity.render-pipelines.core@14.0.12/（简称 core）。为节省篇幅只摘必要片段，省略处用 // ... 标出，原注释大多保留英文原文。其他版本的 URP 在细节上可能不同，以你工程里的实际源码为准。

10.1 全景：Lit 由哪些文件组成

在材质面板上选 “Universal Render Pipeline/Lit”，用到的代码分散在十几个文件里。按 include 关系画出来，主干是这样的：

图 10-1URP Lit 前向 Pass 的主要 include 关系。橙色框是本章重点：光照入口 Lighting.hlsl、BRDF 的 BRDF.hlsl、环境光的 GlobalIllumination.hlsl。

理解 Lit 的关键，是认清三个结构体，它们像接力棒一样传递数据：

SurfaceData（ShaderLibrary/SurfaceData.hlsl）：“这个表面是什么材质”——反照率、金属度、光滑度、切线空间法线、自发光、AO、透明度。由 LitInput.hlsl 采样贴图填写。
InputData（ShaderLibrary/Input.hlsl）：“这个像素在哪儿、朝哪儿”——世界坐标、世界法线、视线方向、阴影坐标、烘焙 GI、屏幕 UV。由 LitForwardPass.hlsl 根据插值器填写。
BRDFData（ShaderLibrary/BRDF.hlsl）：“代入 BRDF 公式的预计算量”——漫反射颜色、F0、α、α² 等。由 InitializeBRDFData 从 SurfaceData 换算而来。

图 10-2一个像素的计算路径：顶点阶段准备插值器，片元阶段先填 SurfaceData 和 InputData，再交给 UniversalFragmentPBR 完成全部光照。

10.2 Lit.shader：属性、Pass 与关键字

Properties

Lit 的属性块很长，按用途可以分成几组（括号里是属性名）：

分组	属性	说明
工作流	`_WorkflowMode`	1 = 金属度，0 = 镜面；只给 ShaderGUI 用，真正起作用的是关键字 `_SPECULAR_SETUP`
基础色	`_BaseMap`、`_BaseColor`、`_Cutoff`	带 `[MainTexture]`/`[MainColor]`，脚本里的 `material.mainTexture`/`color` 指向它们
金属/光滑	`_Metallic`、`_MetallicGlossMap`、`_Smoothness`、`_SmoothnessTextureChannel`	Metallic 贴图 R = 金属度，A = 光滑度（或取自 Albedo 的 A）
镜面工作流	`_SpecColor`、`_SpecGlossMap`	RGB = F0
开关	`_SpecularHighlights`、`_EnvironmentReflections`	`[ToggleOff]`：取消勾选时开启 `_SPECULARHIGHLIGHTS_OFF` 等关键字
细节	`_BumpMap`、`_BumpScale`、`_ParallaxMap`、`_OcclusionMap`、`_EmissionColor`、`_Detail*`	AO 取贴图的 G 通道
渲染状态	`_Surface`、`_Blend`、`_Cull`、`_SrcBlend`、`_ZWrite`…	由 ShaderGUI 根据“不透明/透明”等选项写入，Pass 里以 `Blend[_SrcBlend][_DstBlend]` 形式引用
兼容	`_ClearCoatMask`、`_MainTex`、`_Color`…	为 SRP Batcher 布局一致或旧材质升级而保留，Lit 本身不用

值得注意的是 _ClearCoatMask/_ClearCoatSmoothness：Lit 不支持清漆，但 CBUFFER 里依然留着它们，注释写明是“SRP batching compatibility for Clear Coat”。Complex Lit 与 Lit 共用 LitInput.hlsl，保持相同的 CBUFFER 布局，代码就能共享。

七个 Pass

Pass 名	LightMode	用途	主要文件
ForwardLit	`UniversalForward`	Forward / Forward+ 下的着色	`LitForwardPass.hlsl`
ShadowCaster	`ShadowCaster`	渲染阴影贴图	`ShadowCasterPass.hlsl`
GBuffer	`UniversalGBuffer`	Deferred 路径写 G-Buffer（target 4.5，排除 GLES3/GLCore）	`LitGBufferPass.hlsl`
DepthOnly	`DepthOnly`	深度预渲染、Depth Texture	`DepthOnlyPass.hlsl`
DepthNormals	`DepthNormals`	输出法线纹理（SSAO 等用）	`LitDepthNormalsPass.hlsl`
Meta	`Meta`	烘焙光照贴图时提取反照率和自发光	`LitMetaPass.hlsl`
Universal2D	`Universal2D`	在 2D Renderer 下的回退	`Universal2D.hlsl`

URP 14 的 Lit 只有一个 SubShader，所有 Pass 默认 #pragma target 2.0（GBuffer 除外）。SubShader 的 Tags 里除了常见的 RenderPipeline、RenderType，还有一个 "UniversalMaterialType" = "Lit"：Deferred 渲染时，它决定这个材质在 G-Buffer 里被标记为哪种光照模型（Lit / SimpleLit / Unlit），延迟光照 Pass 据此选择公式。

文件末尾还有两行：FallBack "Hidden/Universal Render Pipeline/FallbackError" 与 CustomEditor "UnityEditor.Rendering.Universal.ShaderGUI.LitShader"。前者意味着当所有 Pass 都无法在当前平台编译时，物体会显示成洋红色的错误材质，而不是悄悄退回某个 Built-in Shader——这就是 URP 里“粉色材质”的来源之一。后者指定了材质面板的 C# 类，它不仅负责画界面，还负责根据选项设置关键字、渲染队列和混合状态（_SrcBlend、_ZWrite 等）。ForwardLit Pass 开头的 Blend[_SrcBlend][_DstBlend], [_SrcBlendAlpha][_DstBlendAlpha]、ZWrite[_ZWrite]、Cull[_Cull] 都是从材质属性读取渲染状态的写法：同一个 Shader 不需要为不透明、透明、双面各写一份 Pass，切换时也不会产生新的 Shader 变体，只改变材质的状态。透明与混合的细节见第 16 章。

关键字：两类来源

ForwardLit Pass 的关键字可以分成两类。材质关键字用 shader_feature_local（或 _fragment 变体）声明，由材质决定、只打包用到的组合：

// 摘自 URP Shaders/Lit.shader（ForwardLit Pass）
#pragma shader_feature_local _NORMALMAP
#pragma shader_feature_local _PARALLAXMAP
#pragma shader_feature_local _RECEIVE_SHADOWS_OFF
#pragma shader_feature_local _ _DETAIL_MULX2 _DETAIL_SCALED
#pragma shader_feature_local_fragment _SURFACE_TYPE_TRANSPARENT
#pragma shader_feature_local_fragment _ALPHATEST_ON
#pragma shader_feature_local_fragment _ _ALPHAPREMULTIPLY_ON _ALPHAMODULATE_ON
#pragma shader_feature_local_fragment _EMISSION
#pragma shader_feature_local_fragment _METALLICSPECGLOSSMAP
#pragma shader_feature_local_fragment _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
#pragma shader_feature_local_fragment _OCCLUSIONMAP
#pragma shader_feature_local_fragment _SPECULARHIGHLIGHTS_OFF
#pragma shader_feature_local_fragment _ENVIRONMENTREFLECTIONS_OFF
#pragma shader_feature_local_fragment _SPECULAR_SETUP

管线关键字用 multi_compile 声明，由 URP 在运行时根据管线设置和场景状态全局开关，所以所有组合都要编译：

// 摘自 URP Shaders/Lit.shader（ForwardLit Pass）
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS _MAIN_LIGHT_SHADOWS_CASCADE _MAIN_LIGHT_SHADOWS_SCREEN
#pragma multi_compile _ _ADDITIONAL_LIGHTS_VERTEX _ADDITIONAL_LIGHTS
#pragma multi_compile _ EVALUATE_SH_MIXED EVALUATE_SH_VERTEX
#pragma multi_compile_fragment _ _ADDITIONAL_LIGHT_SHADOWS
#pragma multi_compile_fragment _ _REFLECTION_PROBE_BLENDING
#pragma multi_compile_fragment _ _REFLECTION_PROBE_BOX_PROJECTION
#pragma multi_compile_fragment _ _SHADOWS_SOFT _SHADOWS_SOFT_LOW _SHADOWS_SOFT_MEDIUM _SHADOWS_SOFT_HIGH
#pragma multi_compile_fragment _ _SCREEN_SPACE_OCCLUSION
#pragma multi_compile_fragment _ _DBUFFER_MRT1 _DBUFFER_MRT2 _DBUFFER_MRT3
#pragma multi_compile_fragment _ _LIGHT_COOKIES
#pragma multi_compile _ _LIGHT_LAYERS
#pragma multi_compile _ _FORWARD_PLUS
// ... 另有 LIGHTMAP_ON、DIRLIGHTMAP_COMBINED、SHADOWS_SHADOWMASK、LOD_FADE_CROSSFADE、
//     multi_compile_fog、DEBUG_DISPLAY、multi_compile_instancing 等

几个容易忽略的细节：

后缀 _fragment 表示该关键字只影响片元着色器，顶点着色器不会因它产生额外变体，能显著减少编译量。
_local 表示关键字作用域是本 Shader，不占用全局关键字名额（Unity 2021.2 起关键字系统经过重做，全局关键字的数量限制已大幅放宽，但材质级的开关仍推荐用 local）。
Forward+ 不是一个独立的 Shader，而是 _FORWARD_PLUS 关键字。自己写的 Shader 如果漏掉这一行，在 Forward+ 渲染器下就收不到附加光——这是从 URP 12 迁移到 14 时最常见的“附加光不亮”原因。
SH 的计算位置由 EVALUATE_SH_MIXED/EVALUATE_SH_VERTEX 控制，对应 URP Asset 里的 SH Evaluation Mode。设置为 Auto 时，URP 在移动平台、XR 移动设备、Switch 上选择逐顶点，其余平台逐像素（见 UniversalRenderPipelineCore.cs 的 ShAutoDetect）。

常见坑：脚本创建的材质没有关键字材质关键字是 Lit 的 ShaderGUI（UnityEditor.Rendering.Universal.ShaderGUI.LitShader）在你修改面板时自动设置的。用代码 new Material(...) 并 SetTexture("_BumpMap", ...)，法线贴图并不会生效，必须同时 EnableKeyword("_NORMALMAP")；运行时切换自发光要 EnableKeyword("_EMISSION")。另外，shader_feature 的变体只有在构建时被某个材质引用到才会打包，运行时才开启的组合在真机上会退回到“最接近的已编译变体”，表现为效果缺失。

10.3 LitInput.hlsl：从贴图到 SurfaceData

LitInput.hlsl 先声明材质常量缓冲：

// 摘自 URP Shaders/LitInput.hlsl
// NOTE: Do not ifdef the properties here as SRP batcher can not handle different layouts.
CBUFFER_START(UnityPerMaterial)
float4 _BaseMap_ST;
float4 _DetailAlbedoMap_ST;
half4 _BaseColor;
half4 _SpecColor;
half4 _EmissionColor;
half _Cutoff;
half _Smoothness;
half _Metallic;
half _BumpScale;
// ... _Parallax、_OcclusionStrength、_ClearCoatMask、_ClearCoatSmoothness、
//     _DetailAlbedoMapScale、_DetailNormalMapScale、_Surface
CBUFFER_END

注释点明了 SRP Batcher 的硬性要求：同一个 Shader 的所有变体，UnityPerMaterial 的布局必须完全一致，所以属性不能放在 #ifdef 里。紧随其后的 UNITY_DOTS_INSTANCING_ENABLED 分支是给 Entities Graphics（DOTS）用的，普通项目可以略过。

然后是几个采样辅助函数。金属度和光滑度的来源取决于两个关键字：

// 摘自 URP Shaders/LitInput.hlsl
half4 SampleMetallicSpecGloss(float2 uv, half albedoAlpha)
{
    half4 specGloss;
#ifdef _METALLICSPECGLOSSMAP
    specGloss = half4(SAMPLE_METALLICSPECULAR(uv));
    #ifdef _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
        specGloss.a = albedoAlpha * _Smoothness;
    #else
        specGloss.a *= _Smoothness;
    #endif
#else // _METALLICSPECGLOSSMAP
    #if _SPECULAR_SETUP
        specGloss.rgb = _SpecColor.rgb;
    #else
        specGloss.rgb = _Metallic.rrr;
    #endif
    // ... 光滑度同理：取 albedoAlpha * _Smoothness 或 _Smoothness
#endif
    return specGloss;
}

有贴图时，_Smoothness 滑条变成贴图 A 通道的乘数；而 _Metallic 滑条在有贴图时完全不起作用（贴图的 R 通道直接当金属度）。这个不对称经常让人困惑：给了金属度贴图后再拖 Metallic 滑条没有反应，是正常的。AO 则通过 LerpWhiteTo(occ, _OcclusionStrength) 在 1 与贴图值之间插值，强度为 0 时等于没有 AO。

最后，InitializeStandardLitSurfaceData 把所有东西填进 SurfaceData：

// 摘自 URP Shaders/LitInput.hlsl
inline void InitializeStandardLitSurfaceData(float2 uv, out SurfaceData outSurfaceData)
{
    half4 albedoAlpha = SampleAlbedoAlpha(uv, TEXTURE2D_ARGS(_BaseMap, sampler_BaseMap));
    outSurfaceData.alpha = Alpha(albedoAlpha.a, _BaseColor, _Cutoff);   // 含 clip

    half4 specGloss = SampleMetallicSpecGloss(uv, albedoAlpha.a);
    outSurfaceData.albedo = albedoAlpha.rgb * _BaseColor.rgb;
    outSurfaceData.albedo = AlphaModulate(outSurfaceData.albedo, outSurfaceData.alpha);

#if _SPECULAR_SETUP
    outSurfaceData.metallic = half(1.0);
    outSurfaceData.specular = specGloss.rgb;
#else
    outSurfaceData.metallic = specGloss.r;
    outSurfaceData.specular = half3(0.0, 0.0, 0.0);
#endif

    outSurfaceData.smoothness = specGloss.a;
    outSurfaceData.normalTS = SampleNormal(uv, TEXTURE2D_ARGS(_BumpMap, sampler_BumpMap), _BumpScale);
    outSurfaceData.occlusion = SampleOcclusion(uv);
    outSurfaceData.emission = SampleEmission(uv, _EmissionColor.rgb, TEXTURE2D_ARGS(_EmissionMap, sampler_EmissionMap));
    // ... 清漆（Lit 中恒为 0）与细节贴图
}

细节贴图（Detail Map）的处理也在这里。ApplyDetailAlbedo 把细节反照率乘 2 后与基础反照率相乘，所以细节贴图的中性值是 0.5 的灰（默认贴图正是 "linearGrey"），比它亮的地方提亮、暗的地方压暗；_DETAIL_SCALED 变体则先按 _DetailAlbedoMapScale 缩放偏离中性值的幅度。细节法线用 BlendNormalRNM（Reoriented Normal Mapping）与主法线混合，再按细节遮罩插值——源码里还留着一条 todo 注释，说更正确的做法应该插值旋转角而不是法线本身。第 7 章讨论过这几种法线混合方式的差别。

镜面工作流下 metallic 被设为 1——这不是说它是金属，而是一个“占位”，因为后面 InitializeBRDFData 在 _SPECULAR_SETUP 下根本不读 metallic。SurfaceData 的定义很短，注释写着它必须与 Shader Graph 的主节点一致——Shader Graph 生成的 Lit Shader 也把数据填进同一个结构，再调用同一个 UniversalFragmentPBR：

// 摘自 URP ShaderLibrary/SurfaceData.hlsl
// Must match Universal ShaderGraph master node
struct SurfaceData
{
    half3 albedo;
    half3 specular;
    half  metallic;
    half  smoothness;
    half3 normalTS;
    half3 emission;
    half  occlusion;
    half  alpha;
    half  clearCoatMask;
    half  clearCoatSmoothness;
};

10.4 LitForwardPass.hlsl：顶点阶段与 InputData

插值器 Varyings 里很多字段被 REQUIRES_* 宏控制。它们在文件开头和 Shadows.hlsl 中定义：

REQUIRES_WORLD_SPACE_TANGENT_INTERPOLATOR：有法线贴图或细节贴图时才传切线。
REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR：只有单级联主光阴影（_MAIN_LIGHT_SHADOWS）或屏幕空间阴影时，阴影坐标在顶点里算好再插值；用级联时必须逐像素选级联，所以在片元里算。
REQUIRES_WORLD_SPACE_POS_INTERPOLATOR：在 Shadows.hlsl 中被无条件定义，世界坐标总会传。

顶点函数 LitPassVertex 做的事情都很直白：GetVertexPositionInputs 得到各空间坐标，GetVertexNormalInputs 得到世界法线与切线；切线的 w 乘上 GetOddNegativeScale()，处理负缩放导致的镜像；没有光照贴图时用 OUTPUT_SH 宏在顶点里算 SH（是否真的在顶点算，取决于上一节的 EVALUATE_SH_*）；雾因子在顶点里算好。

片元阶段的 InitializeInputData 是把插值器“翻译”成 InputData：

// 摘自 URP Shaders/LitForwardPass.hlsl（节选）
void InitializeInputData(Varyings input, half3 normalTS, out InputData inputData)
{
    inputData = (InputData)0;
    inputData.positionWS = input.positionWS;

    half3 viewDirWS = GetWorldSpaceNormalizeViewDir(input.positionWS);
#if defined(_NORMALMAP) || defined(_DETAIL)
    float sgn = input.tangentWS.w;      // should be either +1 or -1
    float3 bitangent = sgn * cross(input.normalWS.xyz, input.tangentWS.xyz);
    half3x3 tangentToWorld = half3x3(input.tangentWS.xyz, bitangent.xyz, input.normalWS.xyz);
    inputData.normalWS = TransformTangentToWorld(normalTS, tangentToWorld);
#else
    inputData.normalWS = input.normalWS;
#endif
    inputData.normalWS = NormalizeNormalPerPixel(inputData.normalWS);
    inputData.viewDirectionWS = viewDirWS;

#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
    inputData.shadowCoord = input.shadowCoord;
#elif defined(MAIN_LIGHT_CALCULATE_SHADOWS)
    inputData.shadowCoord = TransformWorldToShadowCoord(inputData.positionWS);
#else
    inputData.shadowCoord = float4(0, 0, 0, 0);
#endif
    // ... 雾、逐顶点附加光
    inputData.bakedGI = SAMPLE_GI(input.staticLightmapUV, input.vertexSH, inputData.normalWS);
    inputData.normalizedScreenSpaceUV = GetNormalizedScreenSpaceUV(input.positionCS);
    inputData.shadowMask = SAMPLE_SHADOWMASK(input.staticLightmapUV);
}

有两点值得注意。其一，GetWorldSpaceNormalizeViewDir 内部区分了透视与正交投影：正交相机下所有像素的视线方向相同，直接返回相机的前方向取反——所以用正交相机拍 PBR 物体，高光依然正确。其二，bakedGI（烘焙的间接漫反射）在这里就已经采样好了：有光照贴图就采光照贴图，否则用 SH。这意味着 InputData 不只是几何信息，还带着“这个像素收到的环境漫反射辐照度”。

片元函数本身很短：

// 摘自 URP Shaders/LitForwardPass.hlsl（节选）
void LitPassFragment(Varyings input, out half4 outColor : SV_Target0)
{
    // ... 视差映射 ApplyPerPixelDisplacement
    SurfaceData surfaceData;
    InitializeStandardLitSurfaceData(input.uv, surfaceData);
    // ... LOD Cross-Fade
    InputData inputData;
    InitializeInputData(input, surfaceData.normalTS, inputData);
    SETUP_DEBUG_TEXTURE_DATA(inputData, input.uv, _BaseMap);
#ifdef _DBUFFER
    ApplyDecalToSurfaceData(input.positionCS, surfaceData, inputData);
#endif
    half4 color = UniversalFragmentPBR(inputData, surfaceData);
    color.rgb = MixFog(color.rgb, inputData.fogCoord);
    color.a = OutputAlpha(color.a, IsSurfaceTypeTransparent(_Surface));
    outColor = color;
}

流程一目了然：采样材质 → 准备几何 → 贴花修改材质（DBuffer 贴花就是在这一步“改写” SurfaceData 的）→ 光照 → 雾 → 输出。真正的光照全部在 UniversalFragmentPBR 里。

10.5 UniversalFragmentPBR 逐行

UniversalFragmentPBR 是 URP 所有 PBR 类材质（Lit、Complex Lit、Shader Graph 的 Lit Target、粒子 Lit 等）共用的光照总入口，位于 ShaderLibrary/Lighting.hlsl。它接收前面准备好的两个结构体，返回最终颜色。下面的节选去掉了调试分支和清漆的细节，用圆圈数字标出了关键步骤，代码之后逐条解释。

// 摘自 URP ShaderLibrary/Lighting.hlsl（节选，省略 Debug 与清漆细节）
half4 UniversalFragmentPBR(InputData inputData, SurfaceData surfaceData)
{
    #if defined(_SPECULARHIGHLIGHTS_OFF)
    bool specularHighlightsOff = true;
    #else
    bool specularHighlightsOff = false;
    #endif
    BRDFData brdfData;
    // NOTE: can modify "surfaceData"...
    InitializeBRDFData(surfaceData, brdfData);                         // ①

    // ... DEBUG_DISPLAY：CanDebugOverrideOutputColor
    BRDFData brdfDataClearCoat = CreateClearCoatBRDFData(surfaceData, brdfData);
    half4 shadowMask = CalculateShadowMask(inputData);                 // ②
    AmbientOcclusionFactor aoFactor = CreateAmbientOcclusionFactor(inputData, surfaceData);
    uint meshRenderingLayers = GetMeshRenderingLayer();
    Light mainLight = GetMainLight(inputData, shadowMask, aoFactor);   // ③

    MixRealtimeAndBakedGI(mainLight, inputData.normalWS, inputData.bakedGI);   // ④
    LightingData lightingData = CreateLightingData(inputData, surfaceData);

    lightingData.giColor = GlobalIllumination(brdfData, brdfDataClearCoat, surfaceData.clearCoatMask,
                                              inputData.bakedGI, aoFactor.indirectAmbientOcclusion, inputData.positionWS,
                                              inputData.normalWS, inputData.viewDirectionWS, inputData.normalizedScreenSpaceUV);   // ⑤
    // ... _LIGHT_LAYERS 检查
    lightingData.mainLightColor = LightingPhysicallyBased(brdfData, brdfDataClearCoat, mainLight,
                                              inputData.normalWS, inputData.viewDirectionWS,
                                              surfaceData.clearCoatMask, specularHighlightsOff);   // ⑥
    #if defined(_ADDITIONAL_LIGHTS)
    uint pixelLightCount = GetAdditionalLightsCount();
    #if USE_FORWARD_PLUS
    for (uint lightIndex = 0; lightIndex < min(URP_FP_DIRECTIONAL_LIGHTS_COUNT, MAX_VISIBLE_LIGHTS); lightIndex++)
    {
        FORWARD_PLUS_SUBTRACTIVE_LIGHT_CHECK
        Light light = GetAdditionalLight(lightIndex, inputData, shadowMask, aoFactor);
        lightingData.additionalLightsColor += LightingPhysicallyBased(/* 同上 */);
    }
    #endif
    LIGHT_LOOP_BEGIN(pixelLightCount)                                    // ⑦
        Light light = GetAdditionalLight(lightIndex, inputData, shadowMask, aoFactor);
        lightingData.additionalLightsColor += LightingPhysicallyBased(/* 同上 */);
    LIGHT_LOOP_END
    #endif

    #if defined(_ADDITIONAL_LIGHTS_VERTEX)
    lightingData.vertexLightingColor += inputData.vertexLighting * brdfData.diffuse;
    #endif
    return CalculateFinalColor(lightingData, surfaceData.alpha);       // ⑧
}

按编号逐段看：

① InitializeBRDFData：把 SurfaceData 换算成 BRDFData，10.6 节详解。注释“can modify surfaceData”指的是预乘透明（_ALPHAPREMULTIPLY_ON）时会修改 alpha 相关的量。

② ShadowMask 与 AO 因子：CalculateShadowMask 在使用 Shadowmask 光照贴图时读烘焙阴影，否则读光照探针的遮挡 unity_ProbesOcclusion。CreateAmbientOcclusionFactor 把 SSAO 结果与材质 AO 组合成两个数：indirectAmbientOcclusion = min(ssao, 材质AO) 用于间接光，directAmbientOcclusion = lerp(1, ssao, 直接光强度) 用于直接光。也就是说，材质的 AO 贴图只影响间接光，这符合物理：AO 描述的是环境光被遮挡的程度，而直接光的遮挡应当由阴影负责。SSAO 的“Direct Lighting Strength”参数则允许 SSAO 也稍微压暗直接光，属于艺术控制。

③ GetMainLight：返回一个 Light 结构体：方向、颜色（已乘强度，线性空间）、距离衰减、阴影衰减、光照层掩码。阴影衰减在这里通过 MainLightShadow 采样阴影贴图得到；开了 SSAO 时，光的颜色还会乘上 directAmbientOcclusion。

Light 结构体里的四个衰减量

Light 有 direction、color、distanceAttenuation、shadowAttenuation、layerMask 五个字段。主光是方向光，distanceAttenuation 通常为 1（传统 Forward 下它取自 unity_LightData.z，物体被灯的 Culling Mask 排除时为 0，这是“剔除”而不是距离衰减）。附加光的 distanceAttenuation 则包含了距离衰减与聚光灯的角度衰减（第 6 章讲过 URP 的平滑距离衰减公式），shadowAttenuation 是阴影贴图的采样结果。LightingPhysicallyBased 把两个衰减相乘后才乘 $𝐧 \cdot 𝐥$ ，所以对 BRDF 来说，一盏灯无论是哪种类型，最终都被归一成“一个方向 + 一个已衰减的颜色”。这正是 9.3 节“精确光源求和”在代码里的形态。

④ MixRealtimeAndBakedGI：只在“光照贴图 + Subtractive 混合光照”模式下起作用：光照贴图里已经烘进了主光，实时阴影落下时要从光照贴图里减去主光的估计值，否则阴影里会有双重光照。

⑤ GlobalIllumination：间接光（环境漫反射 + 环境反射），10.9 节详解。

⑥ 主光：调用 LightingPhysicallyBased，即直接光的 BRDF × 辐照度，10.8 节详解。

⑦ 附加光：传统 Forward 路径下，GetAdditionalLightsCount() 返回影响当前物体的灯数（逐物体的光源列表，受 URP Asset 中“每物体灯数上限”约束），LIGHT_LOOP_BEGIN 就是一个普通 for 循环。Forward+ 下完全不同：

// 摘自 URP ShaderLibrary/Core.hlsl
#if defined(_FORWARD_PLUS)
#define _ADDITIONAL_LIGHTS 1
#undef _ADDITIONAL_LIGHTS_VERTEX
#define USE_FORWARD_PLUS 1
#else
#define USE_FORWARD_PLUS 0
#endif

// 摘自 URP ShaderLibrary/RealtimeLights.hlsl
#if USE_FORWARD_PLUS
    #define LIGHT_LOOP_BEGIN(lightCount) { \
    uint lightIndex; \
    ClusterIterator _urp_internal_clusterIterator = ClusterInit(inputData.normalizedScreenSpaceUV, inputData.positionWS, 0); \
    [loop] while (ClusterNext(_urp_internal_clusterIterator, lightIndex)) { \
        lightIndex += URP_FP_DIRECTIONAL_LIGHTS_COUNT; \
        FORWARD_PLUS_SUBTRACTIVE_LIGHT_CHECK
    #define LIGHT_LOOP_END } }
#endif

Forward+ 下 _ADDITIONAL_LIGHTS 被强制定义（管线并不会去开这个关键字，见 ForwardLights.cs 里 !m_UseForwardPlus 的条件），循环变成按屏幕分块（cluster）迭代光源列表，lightCount 参数根本没被使用。附加的方向光不进分块列表，所以前面单独有一个 for 循环处理它们。还有一个隐藏约定：宏里直接写了 inputData.normalizedScreenSpaceUV 和 inputData.positionWS——如果你在自己的 Shader 里把 InputData 变量起名为 d 或 input，Forward+ 变体会编译失败。

⑧ CalculateFinalColor：把 LightingData 的五个分量加起来：

// 摘自 URP ShaderLibrary/Lighting.hlsl（节选，去掉了 Debug 开关判断）
half3 CalculateLightingColor(LightingData lightingData, half3 albedo)
{
    half3 lightingColor = 0;
    lightingColor += lightingData.giColor;
    lightingColor += lightingData.mainLightColor;
    lightingColor += lightingData.additionalLightsColor;
    lightingColor += lightingData.vertexLightingColor;
    lightingColor *= albedo;          // PBR 路径传入的 albedo 是 1，不改变结果
    lightingColor += lightingData.emissionColor;
    return lightingColor;
}

各分量本身已经乘过 BRDF，所以 PBR 路径调用 CalculateFinalColor(lightingData, alpha) 时传入的 albedo 是 1。每个累加都包在 IsLightingFeatureEnabled(...) 里，这是 Rendering Debugger 的“Lighting Features”过滤功能：编辑器里可以单独关掉 GI、主光、附加光、自发光来调试——在 DEBUG_DISPLAY 未定义的变体中这些判断恒为真，会被编译器优化掉。

案例 10.1最小 Lit：自己喂数据给 UniversalFragmentPBR进阶单独打开 ↗

目标：写一个只有一百多行的 Lit Shader：自己填 SurfaceData 和 InputData，直接调用 URP 的 UniversalFragmentPBR，光照结果与 URP Lit 一致；同时提供 ShadowCaster、DepthOnly、DepthNormals Pass，并保持 SRP Batcher 兼容。

思路：三个以上的 Pass 要共享同一份 UnityPerMaterial，最稳妥的做法是把 CBUFFER 写进一个 hlsl，所有 Pass 都 include 它。阴影和深度 Pass 不必手写：URP 的 ShadowCasterPass.hlsl、DepthOnlyPass.hlsl 只依赖 _BaseMap、_BaseColor、_Cutoff 这几个名字（_ALPHATEST_ON 时才用到），先 include 我们的输入文件再 include 它们即可。

Assets/Cookbook/Ch10/MinimalLitInput.hlsl

	Lit	Simple Lit
高光模型	GGX + V·F 近似，能量大致守恒	$(𝐧 \cdot 𝐡)^{n}$ ， $n = 2^{10 s + 1}$ （2～2048），未归一化
菲涅尔	有（直接光近似 + 环境光 Pow4）	无
环境反射	反射探针 + EnvironmentBRDF	无（`bakedGI` 只乘 albedo，即只有环境漫反射）
参数	Metallic / Smoothness	Specular Color（RGB），光滑度存在 `_SpecColor.a`
高光开关	默认开，可关	需要关键字 `_SPECULAR_COLOR` 或 `_SPECGLOSSMAP`

目标	RGB	A
GBuffer0	albedo（sRGB 目标）	材质标志位（镜面工作流、关闭高光、不接收阴影等）
GBuffer1	金属度工作流：R = reflectivity；镜面工作流：F0	occlusion
GBuffer2	编码后的世界法线	smoothness
GBuffer3	GI + 自发光（即后续累加光照的缓冲）	—