RPG（上）：地图、移动与对话

[node name="Player" type="CharacterBody2D"]
collision_layer = 4
collision_mask = 3
motion_mode = 1
script = ExtResource("1")

func get_input_vector() -> Vector2:
	if normalize_diagonal:
		# get_vector 把结果的长度限制在 1 以内：同时按右和下得到 (0.707, 0.707)
		return Input.get_vector("move_left", "move_right", "move_up", "move_down")
	# 两个轴各取各的：斜向时是 (1, 1)，长度 √2 ≈ 1.414，跑得比直走快
	return Vector2(Input.get_axis("move_left", "move_right"), Input.get_axis("move_up", "move_down"))

func move(delta: float, input: Vector2) -> void:
	if input != Vector2.ZERO:
		# 朝目标速度逼近，每秒最多改变 acceleration：起步有个很短的加速过程
		velocity = velocity.move_toward(input * speed, acceleration * delta)
		facing = _to_four_way(input)
	else:
		velocity = velocity.move_toward(Vector2.ZERO, friction * delta)
	move_and_slide()

func _make_tileset() -> TileSet:
	var ts := TileSet.new()
	ts.tile_size = Vector2i(T, T)
	ts.add_physics_layer()
	ts.set_physics_layer_collision_layer(PHYS_WORLD, 1)     # 第 1 层 world
	ts.set_physics_layer_collision_mask(PHYS_WORLD, 0)
	ts.add_physics_layer()
	ts.set_physics_layer_collision_layer(PHYS_WATER, 2)     # 第 2 层 water（蝙蝠不检测这一层）
	ts.set_physics_layer_collision_mask(PHYS_WATER, 0)

	var src := TileSetAtlasSource.new()
	src.texture = load("res://art/tiles.png")
	src.texture_region_size = Vector2i(T, T)
	ts.add_source(src, SRC)

	for c in GRASS + [FLOWER_RED, FLOWER_YELLOW, TUFT, PEBBLES, BRIDGE]:
		src.create_tile(c)
	for m in 16:
		src.create_tile(_path(m))
		src.create_tile(_water(m))
		_solid(src, _water(m), PHYS_WATER, _rect(-8, -8, 8, 8))
		src.create_tile(_fence(m))
		var fence: Array[PackedVector2Array] = [_rect(-3, -3, 3, 5)]
		if m & 8: fence.append(_rect(-8, -1, -3, 4))
		if m & 2: fence.append(_rect(3, -1, 8, 4))
		if m & 1: fence.append(_rect(-1, -8, 1, -3))
		if m & 4: fence.append(_rect(-1, 5, 1, 8))
		for poly in fence:
			_solid(src, _fence(m), PHYS_WORLD, poly)
		src.get_tile_data(_fence(m), 0).y_sort_origin = 4
	_obstacle(src, ROCK, Vector2i.ONE, Vector2i.ZERO, _rect(-5, -1, 5, 5), 4)
	_obstacle(src, BUSH, Vector2i.ONE, Vector2i.ZERO, _rect(-7, -3, 7, 5), 4)
	_obstacle(src, STUMP, Vector2i.ONE, Vector2i.ZERO, _rect(-5, -1, 4, 4), 3)
	_obstacle(src, SIGN, Vector2i.ONE, Vector2i.ZERO, _rect(-6, -3, 6, 3), 5)
	# 16×32 的树：图集里占 1×2 格，texture_origin 往上抬 8 像素，让树根落在格子里
	_obstacle(src, TREE, Vector2i(1, 2), Vector2i(0, 8), _rect(-3, 0, 3, 6), 5)
	_obstacle(src, PINE, Vector2i(1, 2), Vector2i(0, 8), _rect(-3, 0, 3, 6), 5)
	# 64×64 的房子：锚点是底边从左数第 2 格
	_obstacle(src, HOUSE, Vector2i(4, 4), Vector2i(-8, 24), _rect(-20, -22, 35, 6), 6)
	return ts


func _solid(src: TileSetAtlasSource, coords: Vector2i, layer: int, poly: PackedVector2Array) -> void:
	var data := src.get_tile_data(coords, 0)
	var i := data.get_collision_polygons_count(layer)
	data.add_collision_polygon(layer)
	data.set_collision_polygon_points(layer, i, poly)


func _obstacle(src: TileSetAtlasSource, coords: Vector2i, size: Vector2i, origin: Vector2i,
		poly: PackedVector2Array, y_sort: int) -> void:
	src.create_tile(coords, size)
	var data := src.get_tile_data(coords, 0)
	data.texture_origin = origin        # 图片相对格子中心的偏移
	data.y_sort_origin = y_sort         # 排序时用的"脚底"位置（相对格子中心）
	_solid(src, coords, PHYS_WORLD, poly)

func _make_world(ts: TileSet) -> void:
	var rows := FileAccess.get_file_as_string("res://dev/map.txt").strip_edges().split("\n")
	var world := Node2D.new()
	world.name = "World"
	world.y_sort_enabled = true
	world.set_script(load("res://world/world.gd"))
	var ground := _layer(world, "Ground", ts)
	ground.z_index = -2                       # 地面永远在最下面
	var decor := _layer(world, "Decor", ts)
	decor.z_index = -1                        # 花草装饰压在地面上、角色下
	var obstacles := _layer(world, "Obstacles", ts)
	obstacles.y_sort_enabled = true           # 树、栅栏、房子和角色一起按 y 排序

	var h := rows.size()
	var w := rows[0].length()
	var at := func(x: int, y: int) -> String:
		if x < 0 or y < 0 or x >= w or y >= h:
			return ""
		return rows[y][x]
	var counts := {}
	for y in h:
		for x in w:
			var c := Vector2i(x, y)
			var ch: String = rows[y][x]
			var r := absi(hash(c)) % 100
			match ch:
				"=":
					ground.set_cell(c, SRC, _path(_mask(at, x, y, "=#", true)))
				"~":
					ground.set_cell(c, SRC, _water(_mask(at, x, y, "~#", true)))
				"#":
					ground.set_cell(c, SRC, BRIDGE)
				_:
					ground.set_cell(c, SRC, GRASS[0 if r < 45 else (1 if r < 80 else (2 if r < 93 else 3))])
			match ch:
				"T":
					obstacles.set_cell(c, SRC, PINE if (x >= 20 and y <= 10) == (r < 80) else TREE)
				"f":
					obstacles.set_cell(c, SRC, _fence(_mask(at, x, y, "f", false)))
				"r":
					obstacles.set_cell(c, SRC, ROCK)
				"b":
					obstacles.set_cell(c, SRC, BUSH)
				"t":
					obstacles.set_cell(c, SRC, STUMP)
				"s":
					obstacles.set_cell(c, SRC, SIGN)
				"H":
					obstacles.set_cell(c, SRC, HOUSE)
				"*":
					decor.set_cell(c, SRC, FLOWER_RED if r % 2 == 0 else FLOWER_YELLOW)
				"'":
					decor.set_cell(c, SRC, TUFT)
				".":
					if r < 4:
						decor.set_cell(c, SRC, PEBBLES)
					elif r < 9:
						decor.set_cell(c, SRC, TUFT)
				"P", "C", "V", "S", "B", "X":
					_spawn(world, ch, ground.map_to_local(c) + Vector2(0, 6), counts)
	var ps := PackedScene.new()
	ps.pack(world)
	ResourceSaver.save(ps, "res://world/world.tscn")
	world.free()


## 4 位掩码：上 1、右 2、下 4、左 8，邻居属于 kinds 时置位。出界当作同类。
func _mask(at: Callable, x: int, y: int, kinds: String, edge_same: bool) -> int:
	var m := 0
	for d: Array in [[0, -1, 1], [1, 0, 2], [0, 1, 4], [-1, 0, 8]]:
		var n: String = at.call(x + d[0], y + d[1])
		if (n == "" and edge_same) or (n != "" and kinds.contains(n)):
			m |= d[2]
	return m

[node name="Camera" type="Camera2D" parent="."]
zoom = Vector2(3, 3)
process_callback = 0
limit_left = 0
limit_top = 0
limit_right = 640
limit_bottom = 352
script = ExtResource("3")

func _physics_process(_delta: float) -> void:
	if target == null:
		return
	if not room_mode:
		global_position = target.global_position
		return
	var room := Vector2i((target.global_position / ROOM_SIZE).floor())
	if room == _room:
		return
	var first := _room == NO_ROOM
	_room = room
	var center := (Vector2(room) + Vector2(0.5, 0.5)) * ROOM_SIZE
	if _tween:
		_tween.kill()
	if first:
		global_position = center
	else:
		_tween = create_tween().set_process_mode(Tween.TWEEN_PROCESS_PHYSICS)
		_tween.tween_property(self, "global_position", center, 0.45).set_trans(Tween.TRANS_SINE)

func _update_interact_target() -> void:
	var best: Node2D = null
	var best_d := INF
	for area in interact_area.get_overlapping_areas():
		var target := area.get_parent() as Node2D
		if target and target.has_method("interact") and target.can_interact():
			var d := global_position.distance_squared_to(target.global_position)
			if d < best_d:
				best = target
				best_d = d
	interact_target = best


func try_interact() -> void:
	if interact_target:
		interact_target.interact(self)

class_name DialogueLine
extends Resource

@export var speaker := ""
@export_multiline var text := ""                 ## 可以写 {left} 这类占位符，见 Game.format_text()
@export var choices: PackedStringArray = []      ## 非空时，这句播完后让玩家选
@export var choice_flags: PackedStringArray = [] ## 选第 i 项时设置的全局标记（可以留空）

class_name Dialogue
extends Resource

@export var require_flag := ""            ## 只有这个标记为真时才会被选中（空 = 无条件）
@export var lines: Array[DialogueLine] = []
@export var flag_on_finish := ""          ## 播完后设置的标记
@export var reward_coins := 0
@export var reward_max_hp := 0            ## 增加的血量上限（半颗心为 1）

[gd_resource type="Resource" script_class="Dialogue" load_steps=6 format=3]

[ext_resource type="Script" path="res://dialogue/dialogue.gd" id="1"]
[ext_resource type="Script" path="res://dialogue/dialogue_line.gd" id="2"]

[sub_resource type="Resource" id="line0"]
script = ExtResource("2")
speaker = "村长"
text = "哦，是你啊，年轻人。"

[sub_resource type="Resource" id="line1"]
script = ExtResource("2")
speaker = "村长"
text = "最近南边草地上冒出好多史莱姆，把庄稼都啃坏了。"

[sub_resource type="Resource" id="line2"]
script = ExtResource("2")
speaker = "村长"
text = "你能帮我打倒 {target} 只史莱姆吗？"
choices = PackedStringArray("没问题，交给我", "我再想想")
choice_flags = PackedStringArray("quest_active", "")

[resource]
script = ExtResource("1")
lines = Array[ExtResource("2")]([SubResource("line0"), SubResource("line1"), SubResource("line2")])

func pick_dialogue() -> Dialogue:
	for d in dialogues:
		if d.require_flag == "" or Game.has_flag(d.require_flag):
			return d
	return null

func _show_line() -> void:
	var line := _dialogue.lines[_index]
	speaker.text = line.speaker
	text.text = Game.format_text(line.text)
	text.visible_characters = 0          # 先一个字都不显示
	_shown = 0.0
	choices.hide()
	_choice = 0

func _process(delta: float) -> void:
	if not panel.visible:
		return
	var total := text.get_total_character_count()
	if text.visible_characters < total:
		_shown += chars_per_sec * delta
		text.visible_characters = mini(int(_shown), total)
	elif not _current_line().choices.is_empty() and not choices.visible:
		_build_choices()
	arrow.visible = text.visible_characters >= total and not choices.visible
	arrow.modulate.a = 1.0 if Time.get_ticks_msec() % 800 < 500 else 0.3

func _unhandled_input(event: InputEvent) -> void:
	if not panel.visible:
		return
	if event.is_action_pressed("interact") or event.is_action_pressed("attack"):
		get_viewport().set_input_as_handled()   # 吞掉这次按键，玩家那边收不到
		if text.visible_characters < text.get_total_character_count():
			text.visible_characters = text.get_total_character_count()   # 没打完：先一下子显示全
			_shown = text.visible_characters
		elif choices.visible:
			_pick(_choice)
		else:
			_next()
	elif choices.visible and (event.is_action_pressed("move_left") or event.is_action_pressed("move_right")):
		get_viewport().set_input_as_handled()
		_choice = wrapi(_choice + (1 if event.is_action_pressed("move_right") else -1), 0, choices.get_child_count())
		_highlight()

func _pick(i: int) -> void:
	var flags := _current_line().choice_flags
	if i < flags.size():
		Game.set_flag(flags[i])
	_next()


func _next() -> void:
	_index += 1
	if _index < _dialogue.lines.size():
		_show_line()
		return
	# 对话结束：把这段对话声明的效果应用到全局状态
	Game.set_flag(_dialogue.flag_on_finish)
	if _dialogue.reward_coins:
		Game.add_coins(_dialogue.reward_coins)
	if _dialogue.reward_max_hp:
		Game.max_hp += _dialogue.reward_max_hp
		Game.change_hp(Game.max_hp)
	panel.hide()
	get_tree().paused = false

[autoload]

Tuning="*res://tuning.gd"
Game="*res://autoload/game.gd"

var max_hp := 6          ## 半颗心为 1，6 = 三颗心
var hp := 6
var coins := 0
var inventory := Inventory.new()
var flags: Dictionary = {}           ## 任务标记，如 {"quest_active": true}
var slimes_killed := 0
var opened_chests: Array[String] = []

signal hp_changed(hp: int, max_hp: int)
signal coins_changed(coins: int)
signal flags_changed
signal toast(text: String)                     ## HUD 底部弹出一行提示
signal dialogue_requested(dialogue: Dialogue)  ## NPC 请求播放对话，由对话框接收
signal loaded                                  ## 读档完成，场景里的宝箱等据此刷新

func _on_hp_changed(hp: int, max_hp: int) -> void:
	for c in _hearts.get_children():
		c.queue_free()
	for i in range(0, max_hp, 2):       # 每颗心代表 2 点血
		var frame := 0 if hp >= i + 2 else (1 if hp == i + 1 else 2)   # 满 / 半 / 空
		_hearts.add_child(_icon(HEARTS, Rect2(frame * 16, 0, 16, 16), 40))