角色移动与跳跃手感

@export var move_force := 900.0
@export var jump_impulse := 420.0


func _ready() -> void:
	lock_rotation = true              # 否则角色会像箱子一样翻滚


func _physics_process(_delta: float) -> void:
	var dir := Input.get_axis("move_left", "move_right")
	apply_central_force(Vector2(dir * move_force, 0))       # 只能"推"它，速度由物理引擎算
	if Input.is_action_just_pressed("jump"):
		apply_central_impulse(Vector2(0, -jump_impulse))    # 是否站在地上，还得自己另外检测

func _physics_process(delta: float) -> void:
	if dead:
		velocity.y = minf(velocity.y + get_gravity_value() * delta, max_fall_speed)
		position += velocity * delta        # 死亡后不再参与碰撞，直接下落出屏幕
		return
	_apply_gravity(delta)
	_handle_jump(delta)
	_handle_horizontal(delta)

	var was_on_floor := is_on_floor()
	if not was_on_floor:
		_fall_speed = velocity.y
	move_and_slide()
	if not was_on_floor and is_on_floor():
		_on_landed()

	_check_hazards()
	if level and global_position.y > level.get_bounds().end.y + 64.0:
		die()
	_update_visual(delta)
	Tuning.stat("速度 x", roundi(velocity.x))
	Tuning.stat("速度 y", roundi(velocity.y))
	Tuning.stat("在地面", is_on_floor())

jump={
"deadzone": 0.2,
"events": [Object(InputEventKey,"resource_local_to_scene":false,"resource_name":"","device":-1,"window_id":0,"alt_pressed":false,"shift_pressed":false,"ctrl_pressed":false,"meta_pressed":false,"pressed":false,"keycode":0,"physical_keycode":32,"key_label":0,"unicode":0,"location":0,"echo":false,"script":null)
, Object(InputEventKey,"resource_local_to_scene":false,"resource_name":"","device":-1,"window_id":0,"alt_pressed":false,"shift_pressed":false,"ctrl_pressed":false,"meta_pressed":false,"pressed":false,"keycode":0,"physical_keycode":87,"key_label":0,"unicode":0,"location":0,"echo":false,"script":null)
, Object(InputEventKey,"resource_local_to_scene":false,"resource_name":"","device":-1,"window_id":0,"alt_pressed":false,"shift_pressed":false,"ctrl_pressed":false,"meta_pressed":false,"pressed":false,"keycode":0,"physical_keycode":4194320,"key_label":0,"unicode":0,"location":0,"echo":false,"script":null)
]
}

func _physics_process(_delta: float) -> void:
	# 轮询：每一帧主动去问"现在按着没有"
	var dir := Input.get_axis("move_left", "move_right")      # -1 ~ 1；手柄摇杆会得到中间值
	var holding := Input.is_action_pressed("jump")            # 这一帧是否按着
	var pressed := Input.is_action_just_pressed("jump")       # 是否"这一帧刚按下"
	var released := Input.is_action_just_released("jump")    # 是否"这一帧刚松开"
	print(dir, holding, pressed, released)

## 事件：有输入发生时引擎调用。适合"按一下触发一次"的操作，比如暂停菜单。
func _unhandled_input(event: InputEvent) -> void:
	if event.is_action_pressed("ui_cancel"):
		get_tree().paused = not get_tree().paused

## 在代码里添加一个动作并绑定按键（一般在 项目设置 → 输入映射 里点出来就行）。
func add_dash_action() -> void:
	if not InputMap.has_action("dash"):
		InputMap.add_action("dash")
	var ev := InputEventKey.new()
	ev.physical_keycode = KEY_SHIFT        # 用物理键位，换了键盘布局位置也不变
	InputMap.action_add_event("dash", ev)

func _handle_horizontal(delta: float) -> void:
	var dir := Input.get_axis("move_left", "move_right")
	var accel := acceleration if is_on_floor() else acceleration * air_control
	if dir != 0.0:
		velocity.x = move_toward(velocity.x, dir * max_speed, accel * delta)
		facing = signf(dir)
	else:
		var decel := friction if is_on_floor() else friction * air_control
		velocity.x = move_toward(velocity.x, 0.0, decel * delta)

## 由"跳多高、多久到顶"反推重力和起跳速度：
##   h = v0·t - ½·g·t²，最高点时 v = v0 - g·t = 0
##   => g = 2h / t²，v0 = 2h / t
func get_gravity_value() -> float:
	return 2.0 * jump_height / (time_to_peak * time_to_peak)


func get_jump_velocity() -> float:
	return -2.0 * jump_height / time_to_peak

func _apply_gravity(delta: float) -> void:
	if is_on_floor():
		return
	var g := get_gravity_value()
	if velocity.y > 0.0:
		g *= fall_multiplier    # 下落比上升更快，跳跃更"干脆"
	velocity.y = minf(velocity.y + g * delta, max_fall_speed)

func _handle_jump(delta: float) -> void:
	# 土狼时间：在地面时一直重置，离开地面后开始倒数
	if is_on_floor():
		_coyote_timer = coyote_time
	else:
		_coyote_timer -= delta

	# 跳跃缓冲：按下跳跃键后，在 jump_buffer 秒内落地都会自动起跳
	if Input.is_action_just_pressed("jump"):
		_buffer_timer = jump_buffer
	else:
		_buffer_timer -= delta

	if _buffer_timer > 0.0 and _coyote_timer > 0.0:
		velocity.y = get_jump_velocity()
		_buffer_timer = 0.0
		_coyote_timer = 0.0
		_on_jumped()

	# 可变跳跃高度：上升途中松开按键，砍掉一部分上升速度
	if Input.is_action_just_released("jump") and velocity.y < 0.0:
		velocity.y *= jump_cut